The Excel TEXTAFTER function returns the text that occurs after a given substring or delimiter. In cases where multiple delimiters appear in the text, TEXTAFTER can return text after the nth occurrence of a delimiter.


Extract text after a delimiter

Return value 

Extracted text string


  • text - The text string to extract from.
  • delimiter - The character(s) that delimit the text.
  • instance_num - [optional] The instance of the delimiter in text. Default is 1.
  • match_mode - [optional] Case-sensitivity. 0 = enabled, 1 = disabled. Default is 0.
  • match_end - [optional] Treat end of text as delimiter. 0 = disabled, 1 = enabled. Default is 0.
  • if_not_found - [optional] Value to return when no match is found. #N/A is default.

How to use 

The Excel TEXTAFTER function extracts text that occurs after a given delimiter. When multiple delimiters appear in the text, TEXTAFTER can return text that occurs after the nth instance of the delimiter. TEXTAFTER can also extract text after a specific delimiter when counting from the end of a text string (i.e., get text after the second to the last delimiter).

  • The output from TEXTAFTER is a single text string that occurs after a matched delimiter.
  • TEXTAFTER takes six arguments, but only the first two are required: text provides the text to process, and delimiter is the substring used to split the text.
  • The instance_num argument indicates which instance of the delimiter to use. For example, to extract the text after the second instance of a delimiter, use 2 for instance_num. If not supplied, instance_num defaults to 1. 
  • By default, TEXTAFTER is case-sensitive (match_mode = 0) and will match case when looking for a delimiter. Set match_mode to 1 to ignore case when matching delimiters.
  • By default, TEXTAFTER will not treat the end of a text string like a delimiter (match_end = 0). To enable this behavior, set match_end to 1.
  • By default, TEXTAFTER will return #N/A when it cannot find the specified delimiter. To return something other than #N/A, provide a value for if_not_found. Note that if match_end is enabled, it will override the value provided for if_not_found.

Note that Excel has three related functions that split text:

  • Use TEXTSPLIT to extract all text separated by a given delimiter.
  • Use TEXTBEFORE to extract the text before a given delimiter.
  • Use TEXTAFTER to extract the text after a given delimiter.

Basic usage

To extract the text that occurs after a specific character or substring, provide the text and the character(s) to use as delimiter in double quotes (""). For example, to extract the first name from "Jones, Bob", provide a comma in double quotes (",") as delimiter:

=TEXTAFTER("Jones,Bob",",") // returns "Bob"

You can use more than one character for delimiter. For example to extract the second dimension in the text string "12 ft x 20 ft", use " x "for delimiter:

=TEXTAFTER("12 ft x 20 ft"," x ") // returns "20 ft"

Note we include a space before and after x, since all three characters function as a delimiter.

Text after delimiter with positive instance number

By default instance_num is positive, and TEXTAFTER will count instances of the delimiter starting from the left, as illustrated in the image below. To get all text before "quick", use 1 for instance number. To get all text before "brown", use 2 for instance number. To extract all text before the last word in the sentence ("dog"), provide 8 for instance_num:

TEXTAFTER with a positive instance number

The formulas below extract text after the first and second occurrence of the hyphen character ("-"):

=TEXTAFTER("ABX-112-Red-Y","-",1) // returns "112-Red-Y"
=TEXTAFTER("ABX-112-Red-Y","-",2 // returns "Red-Y"

TEXTAFTER will return #N/A if the specified instance is not found.

Text after delimiter with negative instance number

One of TEXTAFTER's special tricks is that it also supports negative instance numbers, which makes it possible to work backward from the last delimiter. When instance_num is negative, TEXTAFTER will count from the right, as illustrated below. To extract the last word in the sentence ("dog"), you would use -1 for instance number:

TEXTAFTER with a negative instance number

This is very handy because you don't need to know how many words are in the sentence to begin with. The formulas below extract text after the last and second-to-last hyphen ("-"):

=TEXTAFTER("ABX-112-Red-Y","-",-1) // returns "Y"
=TEXTAFTER("ABX-112-Red-Y","-",-2) // returns "Red-Y"

If instance_num is out-of-range, TEXTAFTER returns an #N/A error.

Match end of text

Normally, TEXTAFTER does not treat the end of a text string as a delimiter. For example, the formula below asks for the text after delimiter 3, counting from the end (note the negative 3):

=TEXTAFTER("ABX-123-Red-XYZ","-",-3) // returns "123-Red-XYZ"

And this formula returns #N/A because there is no fourth delimiter from the end:

=TEXTAFTER("ABX-123-Red-XYZ","-",-4) // returns #N/A

If we enable match_end by providing 1, the formula behaves as if a delimiter exists before "ABX", which is the "end" of the string when counting backward.

=TEXTAFTER("ABX-123-Red-XYZ","-",-4,,1) // returns entire string

Take care in situations where a delimiter cannot be found and match_end is enabled. If match_end is enabled and instance_num is 1, TEXTAFTER will return an empty string ("") if delimiter is not found. If match_end is enabled and instance_num is -1, TEXTAFTER will return the entire string if delimiter is not found. When the target delimiter is found, match_end has no effect. The video below demonstrates how the match_end argument can be used:

Multiple delimiters

To provide multiple delimiters at the same time to TEXTAFTER, you can use an array constant like {"x","y"} where x and y represent different delimiters. One use of this feature is to handle inconsistent delimiters in the source text. For example, in the worksheet below, the delimiter appears as a comma with a space (", ") and a comma without space (","). By providing the array constant {", ",","} for the delimiter, both variations are handled correctly:

=TEXTAFTER(B4,{", ",","})

TEXTAFTER with more than one delimiter


By default, TEXTAFTER is case-sensitive when searching for delimiter. This behavior is controlled by the match_mode argumenta boolean value that enables and disables case-sensitivity. By default, match_mode is FALSE. In the example below, the delimiter appears as both " x " and " X " (upper and lower case "x"). The formula in D4 sets match_mode to TRUE, which disables case-sensitivity and allows TEXTAFTER to match both versions of the delimiter:

=TEXTAFTER(B4," x ",,TRUE) // disable case-sensitivity

TEXTAFTER case sensitive example

Note: you can use 1 and 0 in place of TRUE and FALSE for the match_mode argument.


  • TEXTAFTER is case-sensitive by default.
  • TEXTAFTER will return a #N/A! error if delimiter is not found.
  • TEXTAFTER will return a #VALUE! error if text is empty
  • TEXTAFTER will return #N/A if instance_num is out-of-range.
Dave Bruns Profile Picture

AuthorMicrosoft Most Valuable Professional Award

Dave Bruns

Hi - I'm Dave Bruns, and I run Exceljet with my wife, Lisa. Our goal is to help you work faster in Excel. We create short videos, and clear examples of formulas, functions, pivot tables, conditional formatting, and charts.