## Explanation

In the example shown, we want to sum amounts for both the West and North regions. In other words, we want the total for amounts where region is either West or North. In the example shown, the formula in H6 uses SUMIFS twice:

```
=SUMIF(region,"West",amount)+SUMIF(region,"North",amount)
```

The first SUMIF sums sales in the West, and the second SUMIF sums for sales in the North. The formula then adds these two values together and returns the total.

### SUMIF with an array constant

A more elegant solution is to give the SUMIF function more than one value for the criteria, using an array constant. To do this, construct a normal SUMIF, but package the criteria in array syntax — curly braces, with individual items separated by commas. Finally, wrap the entire SUMIF function in the SUM function. This is necessary because SUMIF will return one result for each item in the criteria array and these results need to be added together:

The formula in cell H7 is:

```
=SUM(SUMIF(region,{"West","North"},amount))
```

### Criteria as reference

If you want to supply criteria as a range (a reference), you'll need to enter as an array formula with control + shift + enter:

```
{=SUM(SUMIF(region,criteria,amount))}
```

where criteria is a range like A1:A2.

### SUMPRODUCT alternative

You can also use SUMPRODUCT to sum cells with OR logic. The formula in cell H8 is:

```
=SUMPRODUCT(amount *((region="West") + (region="North")))
```

This could also be written as:

```
=SUMPRODUCT(amount*(region={"West","North"}))
```

SUMPRODUCT is not as fast as SUMIF, but the speed difference is not noticeable with smaller data sets.