Exceljet

Quick, clean, and to the point

LAMBDA append range horizontal

Excel formula: LAMBDA append range horizontal
Summary 

Excel does not provide a function to append ranges in a horizontal fashion, but you can use the LAMBDA function to create a custom function to combine two ranges, one next to the other. In the example below, the formula in cell C5 is:

=AppendRangeHorizontal(B5:C12,E5:F10,"")

This formula combines the two ranges provided (B5:C12 and E5:F10), by appending the second range to the right of the first range. The result is returned as an array of values that spill into H5:K12. The third argument provides a default value to use when the formula runs into errors combining ranges, for example when ranges have different column or row counts.

Explanation 

Excel does not provide a formula function to append or combine ranges, either horizontally or vertically. You can use Power Query for this task, and this makes sense for data transformations that must be automated and repeated on an on-going basis. However, you can also use the LAMBDA function to create a custom function to combine ranges. This makes sense when you have good control over the data and need a solution that updates automatically, without a refresh step.

In the example below, the formula in cell C5 is:

=AppendRangeHorizontal(B5:C12,E5:F10,"")

This is a custom function created with LAMBDA, based on several Excel functions, including INDEX, SEQUENCE, IFERROR, ROWS, COLUMNS, and MAX. Holding the whole thing together are LAMBDA and LET:

=LAMBDA(range1,range2,default,
  LET(
  rows1,ROWS(range1),
  rows2,ROWS(range2),
  cols1,COLUMNS(range1),
  cols2,COLUMNS(range2),
  rowindex,SEQUENCE(MAX(rows1,rows2)),
  colindex,SEQUENCE(1,cols1+cols2),
  result,
  IF(
    colindex<=cols1,
    INDEX(range1,rowindex,colindex),
    INDEX(range2,rowindex,colindex-cols1)
  ),
  IFERROR(result,default)
  )
)

This formula is based on a formula explained here, adapted to work with columns instead or rows. It's a good example of how the LAMBDA function and LET function work well together. Inside the LET function, the first six lines of code simply assign values to variables. Once values are assigned, these variables drive the output of the function.

The core logic of the formula, the code that builds the combined array, is here:

result,
  IF(
    colindex<=cols1,
    INDEX(range1,rowindex,colindex),
    INDEX(range2,rowindex,colindex-cols1)
  ),
  IFERROR(result,default)
  )

This code can be tricky to read, especially if you're new to LAMBDA functions and dynamic array formulas in general. With line breaks added for readability, it's tempting to read it like a loop, with colindex as an incrementing counter, but colindex is not one value, but an array of 4 values, created with the SEQUENCE function earlier:

colindex,SEQUENCE(1,cols1+cols2) // returns {1,2,3,4)

Similarly, rowindex is an array of 8 numbers:

rowindex,SEQUENCE(rows1+rows2) // returns {1;2;3;4;5;6;7;8} 

The IF function tests the values in colindex all at once. If colindex is less than or equal to the count of the columns in range1 (2), INDEX fetches columns from range1. If the colindex is greater than 2, INDEX fetches columns from range2. In both cases, rowindex is used to retrieve rows.

The array that IF and INDEX create is assigned to the variable result, which is returned as a final value by the formula through the IFERROR function. This is done as a way to catch errors that occur when ranges of different row or column counts are combined. In this case, INDEX will throw an error when it tries to get a values from a non-existent row or column, and the default value will be output instead of the error.

LAMBDA is a beta function available in Excel 365 only.
Author 
Dave Bruns

Excel Formula Training

Formulas are the key to getting things done in Excel. In this accelerated training, you'll learn how to use formulas to manipulate text, work with dates and times, lookup values with VLOOKUP and INDEX & MATCH, count and sum with criteria, dynamically rank values, and create dynamic ranges. You'll also learn how to troubleshoot, trace errors, and fix problems. Instant access. See details here.

Download 100+ Important Excel Functions

Get over 100 Excel Functions you should know in one handy PDF.