# Filter exclude blank values

=FILTER(data,(rng1<>"")*(rng2<>"")*(rng3<>""))

To filter out rows with blank or empty cells, you can use the FILTER function with boolean logic. In the example shown, the formula in F5 is:

=FILTER(B5:D15,(B5:B15<>"")*(C5:C15<>"")*(D5:D15<>""))

The output contains only rows from the source data where all three columns have a value.

The FILTER function is designed to extract data that matches one or more criteria. In this case, we want to apply criteria that requires all three columns in the source data (Name, Group, and Room) to have data. In other words, if a row is missing any of these values, we want to exclude that row from output.

To do this, we use three boolean expressions operating on arrays. The first expression tests for blank names:

B5:B15<>"" // check names

The not operator (<>) with an empty string ("") translates to "not empty". For each cell in the range B5:B15, the result will be either TRUE or FALSE, where TRUE means "not empty" and FALSE means "empty". Because there are 11 cells in the range, we get 11 results in an array like this:

{TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;TRUE}

The second expression tests for blank groups:

C5:C15<>"" // check groups

Again, we are checking 11 cells, so we get 11 results:

{TRUE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE;TRUE}

Finally, we check for blank room numbers:

D5:D15<>"" // check groups

which produces:

{TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;TRUE}

When the arrays that result from the three expressions above are multiplied together, the math operation coerces the TRUE and FALSE values to 1s and 0s. We use multiplication in this case, because we want to enforce "AND" logic: expression1 AND expression2 AND expression3. In other words, all three expressions must return TRUE in a given row.

Following the rules of boolean logic, the final result is an array like this:

{1;0;1;0;1;1;1;0;0;0;1}

This array is delivered directly to the FILTER function as the *include* argument. FILTER only includes the 6 rows that correspond to 1s in the final output.

## Excel Formula Training

Formulas are the key to getting things done in Excel. In this accelerated training, you'll learn how to use formulas to manipulate text, work with dates and times, lookup values with VLOOKUP and INDEX & MATCH, count and sum with criteria, dynamically rank values, and create dynamic ranges. You'll also learn how to troubleshoot, trace errors, and fix problems. Instant access. See details here.

## Download 100+ Important Excel Functions

Get over 100 Excel Functions you should know in one handy PDF.