Summary

To sum if cells contain specific text in another cell, you can use the SUMIF function with a wildcard and concatenation. In the example shown, cell G6 contains this formula:

=SUMIF(C5:C11,"*"&F6&"*",D5:D11)

This formula sums amounts for items in column C that contain "hoodie", anywhere in the cell.

Generic formula

=SUMIF(range,"*"&A1&"*",sum_range)

Explanation 

The SUMIF function supports wildcards. An asterisk (*) means "zero or more characters", while a question mark (?) means "any one character".

Wildcards allow you to create criteria such as "begins with", "ends with", "contains 3 characters" and so on.

So, for example, you can use "*hat*" to match the text "hat" anywhere in a cell, or "a*" to match values beginning with the letter "a".

In this case, we want to match the text in F6. We can't write the criteria like "*F6*" because that will match only the literal text "F6".

Instead, we need to use the concatenation operator (&) to join a reference to F6 to asterisks (*):

"*"&F6&"*"

When Excel evaluates this argument inside the SUMIF function, it will "see" "*hoodie*" as the criteria:

=SUMIF(C5:C11,"*hoodie*",D5:D11)

SUMIF then returns the sum for items that contain "hoodie", which is $27.00 in the example shown.

Note that SUMIF is not case-sensitive.

Sum if cell does not contain

To alter the formula to sum if cells do not contain the specified text, just add the not equal to ("<>") operator to the before the first asterisk (*) like this:

=SUMIF(C5:C11,"<>*"&F6&"*",D5:D11)

This will cause SUMIF to return the sum of cells in D5:D11 when corresponding cells in C5:C11 do not contain "hoodie".

Alternative with SUMIFS

You can also use the SUMIFS function. SUMIFS can handle multiple criteria, and the order of the arguments is different from SUMIF. The equivalent SUMIFS formula is:

=SUMIFS(D5:D11,C5:C11,"*"&F6&"*")

Notice the sum range always comes first in the SUMIFS function.

See this page for a list of available wildcards.

Dave Bruns Profile Picture

AuthorMicrosoft Most Valuable Professional Award

Dave Bruns

Hi - I'm Dave Bruns, and I run Exceljet with my wife, Lisa. Our goal is to help you work faster in Excel. We create short videos, and clear examples of formulas, functions, pivot tables, conditional formatting, and charts.