Split numbers from units of measure

Sometimes you encounter data that mixes units directly with numbers (i.e. 8km, 12v, 7.5hrs). Unfortunately, Excel will treat the numbers in this format as text,  and you won't be able to perform math operations on such values.

To split a number from a unit value, you need to determine the position of the last number.  If you add 1 to that position, you have the start of the unit text. This formula uses this concept to figure out where the unit of measure begins.

In the example shown, the formula in C5 is:

=MAX(ISNUMBER(VALUE(MID(B5,{1,2,3,4,5,6,7,8,9},1)))*{1,2,3,4,5,6,7,8,9})+1

This formula uses the MID function to extract the first 9 values in B5, one character at a time:

MID(B5,{1,2,3,4,5,6,7,8,9},1)

The array constant {1,2,3,4,5,6,7,8,9} is just a simple hack to extract up to 9 characters from a cell value into an array. The result looks like this:

{"8","0","v","","","","","",""}

We then use the VALUE function to convert numbers in text format to actual numbers. The result is:

{8,0,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!}

We run this array through ISNUMBER to get:

{TRUE,TRUE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE}

Then multiply that times another array with 9 numbers to get:

{1,2,0,0,0,0,0,0,0}

We use MAX to get the largest value, which is the position of the "last number", then we add 1 to the position to get the "unit start" position. Finally, we use this position with standard LEFT and RIGHT functions to separate the numbers from the units:

=VALUE(LEFT(B5,C5-1)) // number
=TRIM(RIGHT(B5,LEN(B5)-C5+1)) // unit

Note that the hard-coded number array constant is a hack for convenience, and will only handle raw values up to 9 characters in length.