To convert a measurement in inches to inches and feet (i.e. 53 to 4' 5") you can use a formula based on the INT and MOD functions. In the example shown, the formula in D5 is:

=INT(B5/12)&"' "&MOD(B5,12)&""""

Generic formula

=INT(A1/12)&"' "&MOD(A1,12)&""""


This formula converts a numeric value in inches to text representing the same measurement in inches and feet. To get the value for feet, the INT function is used like this:

=INT(B5/12)&"' "

Inside INT, the value in B5 is divided by 12 and INT simply returns the integer portion of the result, discarding any decimal remainder. The result is then concatenated to a string with a single quote and space character.

To get a value for inches, the MOD function is used like this:


where number comes from B5 and the divisor is 12. Configured in this way, MOD returns the remainder after division. The result is concatenated to two sets of double quotes. The outer pair indicates text, and inner pair is needed for Excel to output a single double quote.

Finally, the INT code and MOD code are concatenated together and Excel returns the final text value.

Rounded inches

To round inches to a given number of decimal places, wrap the MOD function in ROUND. For example, to round inches to one decimal:

=INT(A1/12)&"' "&ROUND(MOD(A1,12),1)&""""

With complete labels

To output a value like "8 feet 4 inches", you adapt the formula like this:

=INT(B5/12)&" feet "&MOD(B5,12)&" inches"

Negative numbers

To work with negative inches as an input, we need to adjust the original formula as follows:

=TRUNC(B5/12)&"' "&MOD(ABS(B5),12)&""""

Here, we replace INT with the TRUNC function and use the ABS function to make sure that number inside MOD is positive. This is necessary because the INT function, contrary to its name, actually rounds negative numbers down away from zero. TRUNC, on the other hand, just chops off the decimal value and keeps the integer with the sign. The MOD function also behaves differently with negative numbers. By wrapping number inside the ABS function, we eliminate this difference. This formula will work fine with positive or negative inches as input. The final result carries the sign of the original inches value.


Dave Bruns Profile Picture

AuthorMicrosoft Most Valuable Professional Award

Dave Bruns

Hi - I'm Dave Bruns, and I run Exceljet with my wife, Lisa. Our goal is to help you work faster in Excel. We create short videos, and clear examples of formulas, functions, pivot tables, conditional formatting, and charts.