Excel formula: Sum if date is between

Generic formula

=SUMIFS(rng1,rng2,">"&A1,rng2,"<"&B1)

Explanation

To sum values that are between two dates, you can use the SUMIFS function. In the example shown, cell H7 contains this formula:

=SUMIFS(amount,date,">"&H5,date,"<"&H6)

where date (C5:C11) and amount (D5:D11) are named ranges.

This formula sums amounts in column D for dates between H5 and H6.

How the formula works

The SUMIFS function allows logical operators (i.e. "=",">",">=", etc.), and multiple criteria.

To match target values between two dates, we need to use two criteria. The SUMIFS function requires that each criteria be entered as a criteria/range pair as follows:

">"&H5,date // greater than H5
"<"&H6,date // less than H6

Note we need to enclose the logical operators in double quotes (""), then concatenate them to cell references with the ampersand (&). This is because SUMIFS is in a group of "RACON" functions that have a unique syntax for criteria.

The final formula looks like this:

=SUMIFS(amount,date,">"&H5,date,"<"&H6)

Note: this example does not include the start or end date in the result. See below for an example that includes start and end dates.

With hard-coded dates

The best way to hard-code dates into the SUMIFS function is to use the DATE function. For example, to sum values in rng1 that are between July 1, 2020 and September 30, 2020, you can use a formula like this:

=SUMIFS(rng1,rng2,">="&DATE(2020,7,1),rng2,"<="&DATE(2020,9,30))

Notice we are using greater than or equal to (">=") and less than or equal to ("<=") so that SUMIFS includes the start and end date in the final result.

Adding more criteria

To extend the formula to apply more criteria, just add another range/criteria pair. For example, the formula below will sum values in rng1 when dates in rng2 are between dates in A1 and B1, AND values in rng3 are equal to C1:

=SUMIFS(rng1,rng2,">"&A1,rng2,"<"&B1, rng3, C1)

Author

Dave Bruns

Related formulas

Sum if date is greater than

To sum if based on dates greater than a certain date, you can use the SUMIF function. In the example shown, cell H5 contains this formula: = SUMIF ( date , ">" & DATE ( 2015 , 10 , 1 ), amount ) This formula sums the amounts in...

Sum if begins with

To sum cells if other cells begin with a specific value, you can use the SUMIF function . In the example shown, the formula in G6 is: = SUMIF ( C5:C11 , "t-shirt*" , D5:D11 ) This formula sums the amounts in column D when a value in column...

Sum if not blank

To sum cells when certain values are not blank, you can use the SUMIF function. In the example shown, cell G6 contains this formula: = SUMIF ( C5:C11 , "<>" , D5:D11 ) This formula sums the amounts in column D only when the value in...

Sum if cells are equal to

To sum numbers based on cells being equal to a certain value, you can use either the SUMIF or SUMIFS functions. In the example shown, we are summing all sales in the West region. The formula in cell H6 is: = SUMIF ( region , "West" ,...

Sum if cells are not equal to

To sum cells when other cells are not equal to a specific value, you can use the SUMIF function. In the example shown, cell H7 contains this formula: = SUMIF ( region , "<>West" , amount ) This formula sums the amounts in column E...

Sum if equal to either x or y

To sum numbers based on other cells being equal to either one value or another (either x or y), you can use the SUMIF function. In the example show, we are summing all sales from either the West OR North region. The formula in cell H6 is: = SUMIF (...

Sum if cells contain specific text

To sum if cells contain specific text, you can use the SUMIF function with a wildcard . In the example shown, cell G6 contains this formula: = SUMIF ( C5:C11 , "*t-shirt*" , D5:D11 ) This formula sums the amounts in column D when a value...

Related functions

Excel SUMIFS Function

SUMIFS is a function to sum cells that meet multiple criteria. SUMIFS can be used to sum values when adjacent cells meet criteria based on dates, numbers, and text. SUMIFS supports logical operators (>,...

Excel DATE Function

The Excel DATE function creates a valid date from individual year, month, and day components. The DATE function is useful for assembling dates that need to change dynamically based on other values in a worksheet.

Excel Formula Training

Formulas are the key to getting things done in Excel. In this accelerated training, you'll learn how to use formulas to manipulate text, work with dates and times, lookup values with VLOOKUP and INDEX & MATCH, count and sum with criteria, dynamically rank values, and create dynamic ranges. You'll also learn how to troubleshoot, trace errors, and fix problems. Instant access. See details here.