## Purpose

## Return value

## Syntax

`=IMEXP(complex_num)`

*complex_num*- The complex number in the form "x+yi".

## How to use

The Excel IMEXP function returns the exponential of a complex number. For example, given "0+πi" as input, the function returns "-1+3.23108914886517E-15i" as output. The output is essentially -1, but due to floating point precision, it contains a very small imaginary component.

```
=IMEXP(COMPLEX(0,PI())) // returns -1 + 3.23108914886517E-15i
```

Given real number input, the function behaves like the exponential function and models exponential growth.

```
=IMEXP(COMPLEX(1,0)) // returns 2.71828182845905
```

Given imaginary input representing an angle, the function returns the corresponding point on the unit circle in the complex plane.

```
=IMEXP(COMPLEX(0,PI()/3)) // returns cos(π/3) + sin(π/3)i
```

### Notation

The complex exponential function often appears as the Latin letter e to some power. This notation is equivalent to passing the complex number as input to the exponential function.

In Excel, we write the exponential of a complex number "z=x+yi" like this:

`=IMEXP(COMPLEX(x,y))`

### Euler's Formula

The complex exponential function appears in a famous math formula called "Euler's Formula," which relates i, π, and -1 together.

We can write another version of this formula that better describes what's happening in terms of the angle θ.

Given imaginary input representing an angle, the function returns the corresponding point on the unit circle in the complex plane. For example, given the input "i π/3" the function returns the point on the unit circle corresponding to the angle of π/3 radians.

In Excel, we can see this behavior in the following formula:

`=IMEXP(COMPLEX(0,PI()/3)) // returns 0.5 + 0.866025404i`

### Explanation

In math, the exponential of a complex number can be expanded using the additive property of exponentials.

The right expression can be expanded further using Euler's Formula.

In Excel, the complex exponential function is equivalent to this formula.

```
=IMPRODUCT(
COMPLEX(EXP(x), 0),
COMPLEX(COS(y), SIN(y))
)
```

From this, we can see the real part of the input governs the magnitude of the output, and the imaginary part of the input governs the phase (angle) of the output. For example, given the input "2+π/3", the function returns a complex number with a magnitude of EXP(2) and an angle of π/3 radians.

`=IMEXP(COMPLEX(2,PI()/3)) // returns 3.694528049 + 6.399110292i`

We can draw the returned complex number in the complex plane like this.

In general, the function's output can be visualized with the 3D plot below. The horizontal XY plane represents input in the complex plane, and the vertical axis represents the magnitude of the output. The plot's surface is colored using the output's phase (angle).

### Polar Form

The complex exponential function can express a complex number in its polar form by describing the number in terms of its radius and angle.

For example, to write the complex number z in Excel with a radius of 5 and an angle of π/4, we scale the point on the complex unit circle given by EXP(iθ) by the radius like this:

```
=IMPRODUCT(
COMPLEX(5,0),
IMEXP(COMPLEX(0,PI()/4))
) // returns 3.535533906 + 3.535533906i
```

We can draw this complex number on the complex plane to visualize its coordinates.

### Inverse

The inverse of the complex exponential function is the complex natural logarithm. For example, if we pass the output of the exponential function for "2+πi" to the natural logarithm, we get "2+πi" as a result.

`=IMLN(IMEXP(COMPLEX(2,PI()))) // returns 2 + πi`

In general, given a complex number, the natural logarithm function returns the natural logarithm of the radius of the number for the real part and the angle of the number for the imaginary part.

Sometimes, this can result in a branch cut, where a different-but-equivalent angle is returned instead.

`=IMLN(IMEXP(COMPLEX(2,3*PI()))) // returns 2 + πi`

This is discussed in more depth in the complex natural logarithm article.

*Images courtesy of *wumbo.net*.*