## Summary

The Excel FLOOR function rounds a given number down to the nearest specified multiple. FLOOR works like the MROUND function, but FLOOR always rounds down.

## Purpose

Round a number down to the nearest specified multiple

## Return value

A rounded number.

## Arguments

• number - The number that should be rounded.
• significance - The multiple to use when rounding.

## Syntax

=FLOOR(number, significance)

## How to use

The Excel FLOOR function rounds a number down to a given multiple. The multiple to use for rounding is provided as the significance argument. If the number is already an exact multiple, no rounding occurs and the original number is returned.

The FLOOR function takes two arguments, number and significance. Number is the numeric value to round down. The significance argument is the multiple to which number should be rounded. In most cases, significance is provided as a numeric value, but FLOOR can also understand time entered as text like "0:15". See the example below.

FLOOR works like the MROUND function, but unlike MROUND, which rounds to the nearest multiple, FLOOR always rounds down.

Note: the FLOOR function is officially listed as a compatibility function, replaced by FLOOR.MATH and FLOOR.PRECISE.

### Examples

The formulas below show how FLOOR rounds down values to a given multiple:

``````=FLOOR(10,3) // returns 9
=FLOOR(40,7) // returns 35
=FLOOR(320,25) // returns 300
=FLOOR(610,100) // returns 600
=FLOOR(-5.4,1) // returns -6
``````

To round a number in A1 down to the nearest multiple of 5, you can use a formula like this:

``````=FLOOR(A1,5)
``````

### Round down to nearest 5

To round a number in A1 down to the nearest multiple of 5:

``````=FLOOR(A1,5) // round down to nearest 5
``````

### Round pricing down to end with .99

FLOOR can be used to set pricing after currency conversion, discounts, etc. For example, the formula below will round a number in A1 down to the next whole dollar, then subtract 1 cent, to return a price like \$2.99, \$5.99, \$49.99, etc.

``````=FLOOR(A1,1)-0.01
``````

You can round pricing up to end in .99 with a similar formula based on the CEILING function:

``````=CEILING(A1,1)-0.01
``````

### Round time down to nearest 15 minutes

FLOOR understands time formats, and can be used to round time down to a given multiple. For example, to round a time in A1 down to the previous 15 minute unit, you can use FLOOR like this:

``````=FLOOR(A1,"0:15") // round time down to nearest 15 min
``````

### Notes

• FLOOR works like the MROUND function, but FLOOR always rounds down.
• If a number is already an exact multiple of significance, no rounding occurs.
• FLOOR rounds positive numbers down toward zero.
• If number is negative, and significance is positive, FLOOR rounds away from zero.
• If number and significance are both negative, FLOOR rounds towards zero.
• For more control over how FLOOR rounds negative numbers, see the FLOOR.MATH function. Author ### Dave Bruns

Hi - I'm Dave Bruns, and I run Exceljet with my wife, Lisa. Our goal is to help you work faster in Excel. We create short videos, and clear examples of formulas, functions, pivot tables, conditional formatting, and charts.