Excel formula: Filter text contains

Generic formula

=FILTER(rng1,ISNUMBER(SEARCH("txt",rng2)))

Explanation

To filter data to include data based on a "contains specific text" logic, you can use the FILTER function with help from the ISNUMBER function and SEARCH function. In the example shown, the formula in F5 is:

=FILTER(B5:D14,ISNUMBER(SEARCH("rd",B5:B14)),"No results")

Which retrieves data where the street column contains "rd".

How this formula works

This formula relies on the FILTER function to retrieve data based on a logical test. The array argument is provided as B5:D14, which contains the full set of data without headers. The include argument is based on a logical test based on the ISNUMBER and SEARCH functions:

ISNUMBER(SEARCH("rd",B5:B14))

In brief, the SEARCH function is set up to look for the text "rd" inside the street data in B5:B14. Because this range includes 10 cells, 10 results are returned. Each result is either a number (text found) or a #VALUE error (text not found):

{#VALUE!;11;#VALUE!;#VALUE!;13;#VALUE!;#VALUE!;18;17;#VALUE!}

And the resulting array returned to the FILTER function as the "include" argument:

{FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE;FALSE}

This array is used by the FILTER function to retrieve matching data. Only rows where the result is TRUE make it into the final output.

Finally, the "if_empty" argument is set to "No results" in case no matching data is found.

Wildcards

The SEARCH function supports wildcards, so the filter logic can include these characters.

Case-sensitive

For a partial match, case-sensitive filter, you can adjust the formula to use the FIND function instead of SEARCH like this:

=FILTER(rng1,ISNUMBER(FIND("TXT",rng2)))

Note: FIND is case-sensitive, but does not support wildcards.

FILTER is a beta function available only through the Office Insiders program.

Author

Dave Bruns

Related formulas

Cell contains specific text

To check if a cell contains specific text, you can use the SEARCH function together with the ISNUMBER function. In the generic version, substring is the specific text you are looking for, and text represents text in the cell you are testing. In the...

Related functions

Excel FILTER Function

The Excel FILTER function filters a range of data based on supplied criteria, and extracts matching records.

Excel SEARCH Function

The Excel SEARCH function returns the location of one text string inside another. SEARCH returns the position of the first character of find_text inside within_text. Unlike FIND, SEARCH allows wildcards, and is not case-sensitive.

Excel ISNUMBER Function

The Excel ISNUMBER function returns TRUE when a cell contains a number, and FALSE if not. You can use ISNUMBER to check that a cell contains a numeric value, or that the result of another function is a number.

Excel Formula Training

Formulas are the key to getting things done in Excel. In this accelerated training, you'll learn how to use formulas to manipulate text, work with dates and times, lookup values with VLOOKUP and INDEX & MATCH, count and sum with criteria, dynamically rank values, and create dynamic ranges. You'll also learn how to troubleshoot, trace errors, and fix problems. Instant access. See details here.