Exceljet

Quick, clean, and to the point

Excel CEILING.MATH Function

Excel CEILING.MATH function
Summary 

The Excel CEILING.MATH function rounds a number up to a specified multiple. Unlike the CEILING function, CEILING.MATH defaults to a multiple of 1, and provides explicit control over rounding direction for negative numbers.

Purpose 
Round a number up to nearest multiple
Return value 
A rounded number.
Syntax 
=CEILING.MATH (number, [significance], [mode])
Arguments 
  • number - The number that should be rounded.
  • significance - [optional] Multiple to use when rounding. Default is 1.
  • mode - [optional] Round negative numbers toward or away from zero. Default is 0.
Version 
Usage notes 

The Excel CEILING.MATH function rounds a number up to a given multiple, where multiple is provided as the significance argument. If the number is already an exact multiple, no rounding occurs and the original number is returned.

The CEILING.MATH function takes three arguments, numbersignificance, and mode. Number is the numeric value to round up, and is the only required argument. With no other input, CEILING.MATH will round number up to the next integer.

The significance argument is the multiple to which number should be rounded. In most cases, significance is provided as a numeric value, but CEILING.MATH can also understand time entered as text like "0:15". The default value of significance is 1.

The mode argument controls the direction negative values are rounded. By default, CEILING.MATH rounds negative values up toward zero. Setting mode to 1 or TRUE changes behavior so that negative values are rounded away from zero. The default value of mode is 0 or FALSE, so you can think of mode as a setting that means "round away from zero". Mode has no effect when number is positive.

Examples

By default, CEILING.MATH rounds to the nearest integer, using a significance of 1.

=CEILING.MATH(1.25) // returns 2

Provide a value for significance to round to a different multiple:

=CEILING.MATH(1.25,3) // returns 3
=CEILING.MATH(4.1,3) // returns 6
=CEILING.MATH(4.1,0.5) // returns 4.5

Rounding negative numbers

By default, positive numbers with decimal portions are rounded up to the nearest integer and negative numbers with decimal portions are rounded toward zero:

=CEILING.MATH(6.3) // returns 7
=CEILING.MATH(-6.3) // returns -6

Control for rounding negative numbers toward zero or away from zero is provided via the optional mode argument. Mode defaults to zero. When mode is zero, or omitted, CEILING.MATH rounds negative numbers toward zero. When mode is 1 or TRUE, CEILING.MATH rounds negative numbers away from zero. Mode has no effect on positive numbers.

=CEILING.MATH(-4.1) // returns -4
=CEILING.MATH(-4.1,1) // returns -4
=CEILING.MATH(-4.1,1,1) // returns -5
=CEILING.MATH(-4.1,1,TRUE) // returns -5

CEILING.MATH vs CEILING

The CEILING.MATH function together with the CEILING.PRECISE function replace the original CEILING function, which is now classified as a "compatibility function". The behavior is very similar, but CEILING.MATH provides explicit control over how negative numbers are rounded. CEILING.MATH differs from CEILING in these key ways:

  1. Rounds up to the next integer by default (i.e. significance defaults to 1)
  2. Provides explicit control for rounding negative numbers (toward zero, away from zero)
  3. Changing the sign of significance has no effect on the result; use mode instead.

Notes

  • To round to the nearest multiple (up or down) see the MROUND function.
  • CEILING.MATH works like CEILING, but provides control for rounding negative values. 
  • The mode argument has no effect on positive numbers.
  • If number is an exact multiple of significance, no rounding occurs.

Download 100+ Important Excel Functions

Get over 100 Excel Functions you should know in one handy PDF.