Excel IMSIN function

Purpose

Get sine of complex number.

Return value

Returns the sine of the complex number.

Syntax

=IMSIN(complex_num)

complex_num - The complex number in the form "x+yi".

Microsoft docs

IMSIN function documentation

Using the IMSIN function

The Excel IMSIN function returns the sine of a complex number. For instance, given "1+1i" as input, the function returns the complex number equal to the sine of the input.

=IMSIN("1+1i") // returns 1.29845758141598+0.634963914784736i

Given real number input, the function behaves like the sine function. For example, given π + 0i as input the function returns 3.23108914886517E-15 (approximately zero). The sine of π is zero, but due to floating-point precision, it returns a very small number close to zero.

=IMSIN(COMPLEX(PI(),0)) // returns 3.23108914886517E-15

Explanation

Mathematically, the sine of a complex number can be represented using a combination of the standard and hyperbolic trigonometric functions.

Definition of sine for a complex number.

If B6 contains a complex number in the form "x+yi", this is equivalent to the following formula.

=COMPLEX(
    SIN(IMREAL(B6))*COSH(IMAGINARY(B6)),
    COS(IMREAL(B6))*SINH(IMAGINARY(B6))
)

Alternatively, the sine of a complex number can be defined in terms of the exponential function, where "z=x+yi".

Sine of a complex number in terms of the exponential function.

If B6 contains a complex number in the form "x+yi", this is equivalent to the following formula.

=IMDIV(
    IMSUB(
        IMEXP(IMPRODUCT(COMPLEX(0,1), B6)), 
        IMEXP(IMPRODUCT(COMPLEX(0,-1), B6))
    ),
    COMPLEX(0, 2)
)

Support Exceljet

Many websites (including Exceljet) have lost over half their traffic in the past year because of the crushing impact of AI on web searches. Exceljet is still at it, publishing free content each week. If you find Exceljet helpful, you can support the site and go ad-free with the Exceljet Lifetime Pass. One payment, no subscription, and ads are gone forever. Plus, you get our Excel Shortcuts video course as a thank you.