## Summary

To count weekdays (Mondays, Fridays, Sundays, etc.) between two dates you can use an array formula that uses several functions: SUMPRODUCT, WEEKDAY, ROW, and INDIRECT. In the example shown, the formula in cell E6 is

``````=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(B6&":"&C6)))=D6))
``````

In the generic version of the formula, start = start date, end = end date, and dow = day of week.

## Generic formula

``=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(start&":"&end)))=dow))``

## Explanation

At the core, this formula uses the WEEKDAY function to test a number of dates to see if they land on a given day of week (dow) and the SUMPRODUCT function to tally up the total.

When given a date, WEEKDAY simply returns a number between 1 and 7 that corresponds to a particular day of the week. With default settings, 1 = Sunday and 7 = Saturday. So, 2 = Monday, 6 = Friday, and so on.

The trick to this formula is understanding that dates in Excel are just serial numbers that begin on Jan 1, 1900. For example, January 1, 2016 is the serial number 42370, and January 8 is 42377. Dates in Excel only look like dates when a date number format is applied.

So, the question becomes - how can you construct an array of dates that you can feed into the WEEKDAY function to find out corresponding days of week?

The answer is to use ROW with INDIRECT functions like so:

``````ROW(INDIRECT(date1&":"&date2))
``````

INDIRECT allows the concatenated dates "42370:42377" to be interpreted as row numbers. Then the ROW function returns an array like this:

``````{42370;42371;42372;42373;42374;42375;42376;42377}
``````

The WEEKDAY function evaluates these numbers as dates and returns this array:

``````{6;7;1;2;3;4;5;6}
``````

which is tested against the given day of week (6 in this case, from D6). Once the results of the test are converted to 1s and 0s with the double hyphen, this array is processed by SUMPRODUCT:

``````{1;0;0;0;0;0;0;1}
``````

Which returns 2.

### With SEQUENCE

With the new SEQUENCE function, this formula can simplified somewhat like this:

``````=SUMPRODUCT(--(WEEKDAY(SEQUENCE(end-start+1,1,start,1))=dow))
``````

In this version, we use SEQUENCE to generate the array of dates directly, with no need for INDIRECT or ROW.

Dynamic Array Formulas are available in Office 365 only. Author ### Dave Bruns

Hi - I'm Dave Bruns, and I run Exceljet with my wife, Lisa. Our goal is to help you work faster in Excel. We create short videos, and clear examples of formulas, functions, pivot tables, conditional formatting, and charts.