Exceljet

Quick, clean, and to the point

Convert date string to date time

Excel formula: Convert date string to date time
Generic formula 
=LEFT(date,10)+MID(date,12,8)
Summary 

To convert a date string to a datetime (date with time) you can parse the text into separate components then build a proper datetime. In the example shown, we are using several functions to perform this task, including DATEVALUE, TIMEVALUE, LEFT and MID. In the worksheet shown, to extract the date, the formula in C5 is:

=DATEVALUE(LEFT(B5,10))

To extract the time, the formula in D5 is:

=TIMEVALUE(MID(B5,12,8))

To assemble a datetime, the formula in E5 is:

=C5+D5
Explanation 

When date information from other systems is pasted or imported to Excel, it may not be recognized as a proper date or time. Instead, Excel may interpret this information as a text or string value only. In this example, the goal is to extract valid date and time information from a text string and convert that information into a datetime. It is important to understand that Excel dates and Excel times are numbers so at a high level, the main task is to convert a text value to the appropriate numeric value.

Date

To get the date, we extract the first 10 characters of the value with the LEFT function:

LEFT(B5,10) // returns "2015-03-01"

The result is text, so to get Excel to interpret as a date, we wrap LEFT in DATEVALUE, which converts the text into a proper Excel date.

Time

To get the time, we extract 8 characters from the middle of the text with the MID function:

MID(B5,12,8) // returns "12:28:45"

Again, the result is text. To get Excel to interpret this value as time, we wrap MID in TIMEVALUE, which converts the text into a proper Excel time.

Datetime

To get a final datetime, we just add the date value to the time value. The formula in E5 is:

=C5+D5

Once you have a valid datetime, use custom number formatting to display the value as desired.

All in one formula

Although this example extracts the date and time separately for clarity, you can combine formulas if you like. The following formula extracts the date and time, and adds them together in one step:

=LEFT(date,10)+MID(date,12,8)

Note that DATEVALUE and TIMEVALUE aren't necessary in this case because the math operation (+) causes Excel to automatically coerce the text values to numbers.

Author 
Dave Bruns

Excel Formula Training

Formulas are the key to getting things done in Excel. In this accelerated training, you'll learn how to use formulas to manipulate text, work with dates and times, lookup values with VLOOKUP and INDEX & MATCH, count and sum with criteria, dynamically rank values, and create dynamic ranges. You'll also learn how to troubleshoot, trace errors, and fix problems. Instant access. See details here.

Download 100+ Important Excel Functions

Get over 100 Excel Functions you should know in one handy PDF.