Exceljet

Quick, clean, and to the point

Count dates by day of week

Excel formula: Count dates by day of week
Generic formula 
=SUMPRODUCT(--(WEEKDAY(dates)=day_num))
Explanation 

To count dates by weekday (i.e. count Mondays, Tuesdays, Wednesdays, etc.), you can use the SUMPRODUCT function together with the WEEKDAY function. In the example shown, the formula in F4 is:

=SUMPRODUCT(--(WEEKDAY(dates,2)=G4))

Note: "dates" is the named range B4:B15.

How this formula works

You might wonder why we aren't using COUNTIF or COUNTIFs? These functions seem like the obvious solution. However, without adding a helper column that contains a weekday value, there is no way to create a criteria for COUNTIF to count weekdays in a range of dates.

Instead, we use the versatile SUMPRODUCT function, which handles arrays gracefully without the need to use Control + Shift + Enter.

We are using SUMPRODUCT with just one argument, which consists of this expression:

--(WEEKDAY(dates,2)=G4)

Working from the inside out, the WEEKDAY function is configured with the optional argument 2, which causes it to return numbers 1-7 for the days Monday-Sunday, respectively. This isn't strictly necessary, but it makes it easier to list the days in order with the numbers in column G in sequence.

WEEKDAY then evaluates each value in the named range "dates" and returns a number. The result is an array like this:

{1;3;7;1;5;2;7;1;7;5;4;7}

The numbers returned by WEEKDAY are then compared to the value in E4, which is 1.

{1;3;7;1;5;2;7;1;7;5;4;7}=1

The result is an array of TRUE/FALSE values.

{TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}

SUMPRODUCT only works with numbers (not text or booleans) so we use the double-negative to coerce the TRUE/FALSE values to one's and zeros:

{1;0;0;1;0;0;0;1;0;0;0;0}

With just this single array to process, SUMPRODUCT sums the items and returns the result, 3.

Dealing with blank dates

If you have blank cells in the list of dates, you will get incorrect results, since the WEEKDAY function will return even when there is no date. To handle empty cells, you can adjust the formula as follows:

=SUMPRODUCT((WEEKDAY(dates,2)=E4)*(dates<>""))

Multiplying by the expression (dates<>"") is one way to cancel out empty cells.

Author 
Dave Bruns

Excel Formula Training

Formulas are the key to getting things done in Excel. In this accelerated training, you'll learn how to use formulas to manipulate text, work with dates and times, lookup values with VLOOKUP and INDEX & MATCH, count and sum with criteria, dynamically rank values, and create dynamic ranges. You'll also learn how to troubleshoot, trace errors, and fix problems. Instant access. See details here.